buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT'
    }
}

apply plugin: 'forge'
apply plugin: 'maven'

version = "1.7.10-0.0.4.3"
group = "ellpeck.actuallyadditions"
archivesBaseName = "ActuallyAdditions"

minecraft {
    version = "1.7.10-10.13.3.1395-1710ls"
    runDir = "idea"
}

repositories {
    maven {
        name "Mobius"
        url "http://mobiusstrip.eu/maven"
    }
    maven {
        name "ChickenBones"
        url "http://chickenbones.net/maven/"
    }
}

dependencies {
    compile "mcp.mobius.waila:Waila:1.5.6_1.7.10"

    /*When Compiling from Github, you will need to have this file present
    because InventoryTweaks doesn't have a Maven Repo.
    But no one is going to download and compile this anyway, so it doesn't really matter. */
    compile files("lib/InventoryTweaks-api-1.58-147.jar")
}

task copyChickenBones(type: Copy, dependsOn: "extractUserDev") {
    from { configurations.compile }
    include "**/*Chicken*.jar", "**/*NotEnoughItems*.jar"
    exclude "**/CodeChickenLib*"
    into file("./run/mods")
    mustRunAfter "deobfBinJar"
    mustRunAfter "repackMinecraft"
}

processResources{

    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
                
        expand 'update':project.version, 'mcversion':project.minecraft.version
    }
        
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

sourceSets {
    main {
        output.resourcesDir = output.classesDir
    }
}