ActuallyAdditions/build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT'
    }
}

apply plugin: 'forge'
apply plugin: 'maven'

version = "1.7.10-r20"
group = "de.ellpeck.actuallyadditions"
archivesBaseName = "ActuallyAdditions"

minecraft {
    version = "1.7.10-10.13.4.1558-1.7.10"
    runDir = "idea"

    replaceIn "ModUtil.java"
    replace "@VERSION@", project.version.toString()
}

repositories {
    maven {
        name "Mobius"
        url "http://mobiusstrip.eu/maven"
    }
    maven {
        name "ChickenBones"
        url "http://chickenbones.net/maven/"
    }
}

dependencies {
    compile "mcp.mobius.waila:Waila:1.5.10_1.7.10"
    compile "codechicken:CodeChickenLib:1.7.10-1.1.3.138:dev"
    compile "codechicken:CodeChickenCore:1.7.10-1.0.7.46:dev"
    compile "codechicken:NotEnoughItems:1.7.10-1.0.5.110:dev"
}

processResources {
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'

        expand 'version': project.version, 'mcversion': project.minecraft.version
    }

    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

// Why is OpenComputers one of the only mods that has a readable build.gradle? (Thank you Sangar!) :D
jar {}

task deobfJar(type: Jar) {
    from sourceSets.main.output
    classifier = 'dev'
}

task apiJar(type: Jar) {
    from sourceSets.main.output
    from sourceSets.main.java
    classifier = 'api'
    include 'de/ellpeck/actuallyadditions/api/**'
}